build.gradle.kts

import org.jetbrains.intellij.platform.gradle.IntelliJPlatformType

plugins {
    kotlin("jvm") version "2.4.20"
    id("org.jetbrains.intellij.platform") version "2.19.0"
}

group = providers.gradleProperty("pluginGroup").get()
version = providers.gradleProperty("pluginVersion").get()

repositories {
    mavenCentral()
    intellijPlatform {
        defaultRepositories()
    }
}

dependencies {
    intellijPlatform {
        create(providers.gradleProperty("platformType"), providers.gradleProperty("platformVersion"))
    }
}

kotlin {
    jvmToolchain(21)
}

intellijPlatform {
    pluginConfiguration {
        name = providers.gradleProperty("pluginName")
        version = providers.gradleProperty("pluginVersion")
        description = "Support for Tiltfile: syntax highlighting and completion."
        ideaVersion {
            sinceBuild = "243"
            // No upper bound: the plugin only uses stable platform APIs, so it
            // should keep working on newer IDEs without a release per version.
            untilBuild = provider { null }
        }
    }

    pluginVerification {
        ides {
            // Latest IntelliJ Community release of every major since sinceBuild.
            recommended()
            // The plugin depends only on the core platform, so it should run in
            // every JetBrains IDE. Spot-check the latest release of a couple of others.
            create(IntelliJPlatformType.PhpStorm, "2026.2.3")
            create(IntelliJPlatformType.GoLand, "2026.2.3")
        }
    }
}